Option Explicit

'//

'// Use MCI functions to record a WAV file.

'// The main MCI function is mciSendString, that sends command

'// strings to the system MCI device and executes them.

'// The device that the command is sent to is specified in the command string.

'// In this case it is the waveaudio

'//

Private Declare Function mciSendString Lib "winmm" _

   Alias "mciSendStringA" ( _

   ByVal lpstrCommand As String, _

   ByVal lpstrReturnString As String, _

   ByVal uReturnLength As Long, _

   ByVal hwndCallback As Long) As Long



Private Declare Function mciExecute Lib "winmm" ( _

   ByVal lpstrCommand As String) As Long



Private Declare Function sndPlaySound Lib "winmm.dll" _

   Alias "sndPlaySoundA" ( _

   ByVal lpszSoundName As String, _

   ByVal uFlags As Long) As Long

    

'// Sound constants

Private Const SND_SYNC = &H0

Private Const SND_ASYNC = &H1

Private Const SND_NODEFAULT = &H2

Private Const SND_LOOP = &H8

Private Const SND_NOSTOP = &H10





'// Define your Alias handle

Private Const strAlias As String = "RcrdWavFile "

Private Const strOpenCmd As String = "Open new type waveaudio alias " & strAlias

Private Const strRecordCmd As String = "Record " & strAlias

Private Const strTimeCmd As String = "Record " & strAlias & " to "

'// Note the time length in msecs comes before this const eg 10000 WAIT

Private Const strWaitCmd As String = " WAIT"

Private Const strSaveCmd As String = "Save " & strAlias

Private Const strCloseCmd As String = "Close " & strAlias

'// Save recorded sound as

Private Const strSaveAs As String = "C:\test.wav"



Sub TestRecording()

Dim strCommand As String

Dim ExecCmd As Long

Dim tWait



'// Define Time to record for in Secs

tWait = 5



'// Open default recorder > Dosen't Show

ExecCmd = mciSendString(strOpenCmd, vbNullString, 0, 0&)

'// Start recording

ExecCmd = mciSendString(strRecordCmd, vbNullString, 0, 0&)

'// Set the Recording time

ExecCmd = mciSendString(strTimeCmd & (tWait * 1000) & strWaitCmd, _

   vbNullString, 0, 0&)

'// Save the recorded sound

ExecCmd = mciSendString(strSaveCmd & strSaveAs, vbNullString, 0, 0&)

'// Now close the Handle

ExecCmd = mciSendString(strCloseCmd, vbNullString, 0, 0&)



'// Tell the user it has finsihed

MsgBox "Finished recording", vbInformation



End Sub



Sub PlayBack()

   WAVPlay strSaveAs

End Sub



Sub PlayBackLoop()

   WAVLoop strSaveAs

End Sub



Sub PlayBackStop()

'// If your going o play a Loop then you need to STOP IT!

    Call WAVPlay(vbNullString)

End Sub





Sub WAVLoop(File As String)

    Dim SoundName As String

    Dim wFlags As Long

    Dim x As Long

    

    SoundName = File

    wFlags = SND_ASYNC Or SND_LOOP

    x = sndPlaySound(SoundName, wFlags)

    If x = 0 Then MsgBox "Can't play " & File



End Sub



Sub WAVPlay(File As String)

    Dim SoundName As String

    Dim wFlags As Long

    Dim x As Long

    

    SoundName = File

    wFlags = SND_ASYNC Or SND_NODEFAULT

    x = sndPlaySound(SoundName, wFlags)

    If x = 0 Then MsgBox "Can't play " & File



End Sub